[Java] Why should the where clause still have source.getNode().asExpr() = f.getAnAccess() ?

[SummerSec]

I have encountered a confusion, who can help me?

/**
 *@name PIIQueryPath
 *@kind path-problem
 *@description 污染路径
 */

import java
import semmle.code.java.StringFormat
import semmle.code.java.dataflow.TaintTracking
import DataFlow::PathGraph


class SenInfoField extends Field{
    SenInfoField(){
        (this.getName().matches("%email%") or
        this.getName().matches("%phone%") or
        this.getName().matches("creditCard%")) and
        this.fromSource()
    }
}

class MySenInfoTaintConfig extends TaintTracking::Configuration{
    MySenInfoTaintConfig(){
        this = "MySenInfoTaintConfig"

    }

    override predicate isSource(DataFlow::Node source){
        source.asExpr() = any(SenInfoField sif).getAnAccess()
    }
    override predicate isSink(DataFlow::Node sink){
        sink.asExpr() = any(LoggerFormatMethod lfm).getAReference().getAnArgument()
    }
}

from MySenInfoTaintConfig config, DataFlow::PathNode source, DataFlow::PathNode sink, SenInfoField f
where 
    config.hasFlowPath(source, sink) and
    source.getNode().asExpr() = f.getAnAccess()
select sink,source,sink ,"PII data from field $@ is written to long here",f,f.getName()

There is no problem with the above QL query
But when I use the following QL query, I get an error

from MySenInfoTaintConfig config, DataFlow::PathNode source, DataFlow::PathNode sink
where config.hasFlowPath(source, sink)
select sink, source, sink, "PII data from field is written to long here",source

Exception during results interpretation: Interpreting query results failed: A fatal error occurred: Could not process query metadata.
Error was: Expected result pattern(s) are not present for query kind "path-problem": Expected the columns after the fourth column to alternate between entity/string and string. [INVALID_RESULT_PATTERNS]
[2021-04-17 15:11:18] Exception caught at top level: Could not process query metadata.
                      Error was: Expected result pattern(s) are not present for query kind "path-problem": Expected the columns after the fourth column to alternate between entity/string and string. [INVALID_RESULT_PATTERNS]
                      com.semmle.cli2.bqrs.InterpretCommand.executeSubcommand(InterpretCommand.java:123)
                      com.semmle.cli2.picocli.SubcommandCommon.executeWithParent(SubcommandCommon.java:414)
                      com.semmle.cli2.execute.CliServerCommand.lambda$executeSubcommand$0(CliServerCommand.java:67)
                      com.semmle.cli2.picocli.SubcommandMaker.runMain(SubcommandMaker.java:201)
                      com.semmle.cli2.execute.CliServerCommand.executeSubcommand(CliServerCommand.java:67)
                      com.semmle.cli2.picocli.SubcommandCommon.call(SubcommandCommon.java:430)
                      com.semmle.cli2.picocli.SubcommandMaker.runMain(SubcommandMaker.java:201)
                      com.semmle.cli2.picocli.SubcommandMaker.runMain(SubcommandMaker.java:209)
                      com.semmle.cli2.CodeQL.main(CodeQL.java:91)
. Will show raw results instead.
Starting CodeQL CLI Server using CodeQL CLI: D:\codeql\codeql\codeql execute cli-server -v --log-to-stderr
CodeQL CLI Server started on PID: 20312
Reading bqrs header using CodeQL CLI: bqrs info -v --log-to-stderr --format json --paginate-rows 200 C:\Users\Samny\AppData\Local\Temp\queries_-15572-bBTSL3uDkwFM\results5.bqrs...
CLI command succeeded.

So I have a few questions.

1. Why should the where clause have

source.getNode().asExpr() = f.getAnAccess()

2. where can I know the template for data flow writing

[SummerSec]

我想我已经知道了，相同＝并不是赋值

[smowton]

Translates as: I think I already know that the same = is not an assignment

[smowton]

The error occurs because select sink, source, sink, "PII data from field is written to long here",source has the wrong number of columns:

The columns after the 4th are to replace any $@ placeholders, and should come in pairs

So select sink, source, sink, "PII data from field is written to long here" is good
as is select sink, source, sink, "PII data from field is written to long here $@", someLocatable, "description",
as is select sink, source, sink, "PII data from field is written to long here $@ $@", someLocatable1, "description1", someLocatable2, "description2"

[smowton]

Information about path-problem queries: https://codeql.github.com/docs/writing-codeql-queries/creating-path-queries/
Information about $@ placeholders: https://codeql.github.com/docs/writing-codeql-queries/defining-the-results-of-a-query/